Amiga Format CD 34/Amiga Format CD34 (1998-11-20)(Future Publishing)(GB)[!][Christmas issue].iso/-websites-/amosfactory/downloads/amosgrab.lha/AMOSGrab_100.AMOS/AMOSGrab_100.amosSourceCode

AMOS Source Code | 1998-08-18 | 7KB | 262 lines

Procedure _AMOSGRAB_100



   '--- amosgrab v1.00 (18/08/98)
   '--- rune j. keller ([e-mail])



   Dim _PLANES(7)
   Dim _WIDTH(7)
   Dim _HEIGHT(7)
   Dim _POSX(7)
   Dim _POSY(7)
   Dim _OFFX(7)
   Dim _OFFY(7)
   Dim _HIDDEN(7)



   '--- bobs to check

   _MAXBOBS=32

   '--- sprites to check

   _MAXSPRITES=8

   '--- create logfile?

   _LOGFILE=True

   '--- destination directory

   _DIR$="T:"



   '--- delete old grabs

   For _SCREEN=0 To 7

      If Exist(_DIR$+"AMOSGrab_"+Str$(_SCREEN)-" "+".LBM")

         Kill _DIR$+"AMOSGrab_"+Str$(_SCREEN)-" "+".LBM"

      End If

   Next



   If _LOGFILE=True

      Open Out 1,_DIR$+"AMOSGrab_Log.TXT"

      Print #1,"AMOSGrab 1.00 (18/08/98)"
      Print #1,"Rune J. Keller ([e-mail])"
      Print #1,"Logfile"

      Close 1

   End If



   '--- check all screens

   For _SCREEN=0 To 7

      Trap Screen _SCREEN

      '--- if screen exists

      If Errtrap=0

         _PLANES(_SCREEN)=Peek(Screen Base+$51)
         _POSX(_SCREEN)=Deek(Screen Base+$C2)
         _POSY(_SCREEN)=Deek(Screen Base+$C4)
         _WIDTH(_SCREEN)=Deek(Screen Base+$C8)
         _HEIGHT(_SCREEN)=Deek(Screen Base+$CA)
         _OFFX(_SCREEN)=Deek(Screen Base+$CE)
         _OFFY(_SCREEN)=Deek(Screen Base+$D0)

         If Peek(Screen Base+$B4)=$80
            _HIDDEN(_SCREEN)=True
         End If

         If _LOGFILE=True

            Append 1,_DIR$+"AMOSGrab_Log.TXT"

            Print #1,""
            Print #1,"Screen ";_SCREEN

            If _HIDDEN(_SCREEN)=True
               Print #1,"Hidden"
            End If

            Print #1,"Planes ";_PLANES(_SCREEN)
            Print #1,"PosX   ";_POSX(_SCREEN)
            Print #1,"PosY   ";_POSY(_SCREEN)
            Print #1,"Width  ";_WIDTH(_SCREEN)
            Print #1,"Height ";_HEIGHT(_SCREEN)
            Print #1,"OffX   ";_OFFX(_SCREEN)
            Print #1,"OffY   ";_OFFY(_SCREEN)

            Close 1

         End If

      End If

   Next



   '--- get free screen to work on

   For _DEST=0 To 7

      '--- found free screen

      If _PLANES(_DEST)=0

         '--- get source screens

         For _SOURCE=0 To 7

            If _PLANES(_SOURCE)>0

               '--- open new work screen

               Screen Open _DEST,_WIDTH(_SOURCE),_HEIGHT(_SOURCE),2^_PLANES(_SOURCE),Lowres

               Screen Hide _DEST

               '--- copy layers

               Screen Copy _SOURCE,_OFFX(_SOURCE),_OFFY(_SOURCE),_OFFX(_SOURCE)+_WIDTH(_SOURCE),_OFFY(_SOURCE)+_HEIGHT(_SOURCE) To _DEST,0,0

               Screen _DEST

               '--- copy bobs and sprites

               If _HIDDEN(_SOURCE)=False

                  '--- get bobs on screen

                  For _BOB=0 To _MAXBOBS-1

                     Trap _IMAGE=I Bob(_BOB)

                     If Errtrap=0 and _IMAGE<>0

                        _REV=0

                        _IMAGE=I Bob(_BOB)

                        '--- bob is reversed

                        If _IMAGE<0

                           If _IMAGE<0 and _IMAGE>-$4000
                              _IMAGE=_IMAGE+$4000
                              _REV=$4000
                           Else If _IMAGE<$4000 and _IMAGE>-$8000
                              _IMAGE=_IMAGE+$8000
                              _REV=$8000
                           Else If _IMAGE<-$8000
                              _IMAGE=_IMAGE+$C000
                              _REV=$C000
                           End If

                        End If

                        _POSX=X Bob(_BOB)
                        _POSY=Y Bob(_BOB)

                        '--- get hot spot

                        _HOTSPOTX=Deek(Leek(Start(1)+2+(_IMAGE-1)*8)+6)
                        _HOTSPOTY=Deek(Leek(Start(1)+2+(_IMAGE-1)*8)+8)

                        '--- remove the flipping flags

                        If _HOTSPOTX>$C000
                           _HOTSPOTX=_HOTSPOTX-$C000
                        Else If _HOTSPOTX>$8000
                           _HOTSPOTX=_HOTSPOTX-$8000
                        Else If _HOTSPOTX>$4000
                           _HOTSPOTX=_HOTSPOTX-$4000
                        End If

                        _POSX=_POSX-_HOTSPOTX
                        _POSY=_POSY-_HOTSPOTY

                        Paste Bob _POSX-_OFFX(_SOURCE),_POSY-_OFFY(_SOURCE),_IMAGE+_REV

                     End If

                  Next

                  '--- get sprites on screen

                  For _SPRITE=0 To _MAXSPRITES-1

                     Trap _IMAGE=I Sprite(_SPRITE)

                     If Errtrap=0 and _IMAGE<>0

                        _IMAGE=I Sprite(_SPRITE)
                        _POSX=X Screen(X Sprite(_SPRITE),_SOURCE)
                        _POSY=Y Screen(Y Sprite(_SPRITE),_SOURCE)

                        _HOTSPOTX=Deek(Leek(Start(1)+2+(_IMAGE-1)*8)+6)
                        _HOTSPOTY=Deek(Leek(Start(1)+2+(IMAGE-1)*8)+8)

                        _POSX=_POSX-_HOTSPOTX
                        _POSY=_POSY-_HOTSPOTY

                        Paste Bob _POSX-_OFFX(_SOURCE),_POSY-_OFFY(_SOURCE),_IMAGE

                     End If

                  Next

               End If

               '--- get correct palette

               Screen _DEST

               Get Palette _SOURCE

               '--- save work screen

               Save Iff _DIR$+"AMOSGrab_"+Str$(_SOURCE)-" "+".LBM"

               '--- close old work screen

               Screen Close _DEST

            End If

         Next

         Exit

      End If

   Next



   '--- no free screen to work on!

   If _DEST=8 Then Pop Proc[-1]



End Proc[0]